分类目录归档:Perl

perl模块MIME::Lite发送中文邮件

学perl注定是要孤独的,如果可以从头来过,学python吧,毕竟perl的圈子太小了,就那几个qq群,问题太浅人家不想鸟你,太深的知识自己也不会

今天有个群友告诉我 www.maildir.cn 的邮件不能用了,唉,以前都一直好好的,不知道最近为什么居然出错了。不管怎么样,反正就是出错了,发不出邮件

因为电脑不好出错了  大约问题是 net::cmd 这个模块,,使用宽字符,大约如下

Wide character in syswriteat /usr/lib/perl5/5.8.8/Net/Cmd.pm line 436.

后来google了一下,再加上调试总算把问题解决了,,所以留下点笔记,以帮助其它人

    my $msg=MIME::Lite->new(
            From=>$opt->{from},
            To=>$opt->{to},
            #Subject=>$opt->{subject},
			Subject=>"=?UTF-8?B?" .encode_base64(encode("utf8", $opt->{subject}), "") . "?=",
            #Type => 'text/html',
            #'Content-transfer-encoding'=>'7bit',
            Data =>encode("utf8", $opt->{body}),
			Encoding => 'base64',
    );
    $msg->attr("content-type.charset" => "UTF-8");

    #$msg->send('smtp','wwww.maildir.cn',Debug=>0);

以上代码只能作为参考,不能直接作用,主要是两个地方,1、主题 要用utf8编码 即是

"=?UTF-8?B?" .encode_base64(encode("utf8", $opt->{subject}), "") . "?="

2、邮件内容需要,encode 一下

 Data =>encode("utf8", $opt->{body}),

参考

https://www.databasesandlife.com/using-utf-8-and-unicode-data-with-perl-mimelite/

使用Rex::WebUI的问题

安装好 Rex::WebUI ,在使用时,报下面的错误

Can’t locate object method “secret” via package “Rex::WebUI” at /usr/local/share/perl5/Mojo/Server.pm line 17.

大约是说没有找到secret 这个方法,后来在google找了一下。应该是mojo升级了产生的问题

找到/usr/local/share/perl5/Rex/WebUI.pm  这个文件 ,选择执行 chmod 644  WebUI.pm

找到 42行,把  $self->secret$secret);  改为  $self->secrets($secret);  secret多了一个s

参考

https://github.com/ldidry/lstu/issues/7

通过linux-inotify刷新fikker-cdn免登录版

因为之前对fikker 不了解,所以就写了一个登录的,登录后会遇到session 超时的问题,当然程序有自动重新登录的功能,但是登录是多一个过性能肯定没有一步到位好。好了,是时候贴代码了,

如果你想后台运行 后面加 & 就可以了。。如果你是ssh 上去 ,怕退了后自动关闭,就用nohup命令运行吧,当然有能力可以用 app::daemon 模块做成后台进程。

对于目录太大的文件夹,执行起来会慢点,建议用sersync -m socket 用socket 发送更新的文件

use strict;
use EV;
use 5.010;
use Data::Dumper;
use Date::Format;
use Mojo::UserAgent;
use URI::Escape;
use AnyEvent::Inotify::Simple;

# Fikker cdn server's 
# WARNNING: do not add "/" on url end.
my $server={
	srv1=>{ url=>'http://192.168.1.99:6780',passwd=>'abc123'},
	srv2=>{ url=>'http://192.168.1.88:6780',passwd=>'abc123'},
};

# Monittor DIR
my $dir='/root/test';

#Full path of Site url
my $site_url='http://www.yiyou.org/';

# open debug =1 ,close = 0
my $debug=1;

#   ===== END CONFIG ====
my $ua = Mojo::UserAgent->new;

our $queue;

my $w = EV::timer 2, 2, sub {
   my $q=$queue;
   $queue={};
   #say "timer print";
   for my $key(keys %{$q}){
		#say  "=>",$key;
		my $url=uri_escape($site_url.$key);
		say "site url $url" if $debug;
		
		for my $srv(keys %{$server}){
			my $try=3;
			do{
				my $srv_passwd=$server->{$srv}->{passwd};
				my $get_url=$server->{$srv}->{url}."/fikker/webcache.fik?type=thiscache&cmd=cleancache&Username=admin&Password=$srv_passwd&Icase=0&Rules=2&WithCluster=1&Url=$url";
				my $res=$ua->get($get_url)->res->json;
				#print Dumper $res;
				if($res->{Return} eq  "False" ){
					warn "refresh url $url fail.";
				}else{
					$try=-1;
				}
				$try --;
				say "try $try" if $debug;
			}while($try > 0);
		}
   }
};
my $inotify = AnyEvent::Inotify::Simple->new(
    directory      => $dir,
    event_receiver => sub {
        my ($event, $file, $moved_to) = @_;
		#print Dumper $event;
		given($event) {
			when('modify'){
				$queue->{$file}=1;
				#say "modify => $file" if $debug;
			}
			when('delete'){
				$queue->{$file}=1;
				#say "modify => $file" if $debug;
			}
        };

    },
);

EV::loop;

 

通过linux-inotify事件刷新fikker-cdn

如果文件更新就刷新cdn这个是很多运维需要做的,现在用perl开发了这个脚本,由于这个cpan模块块扫描目录很慢,所以建用在文件不多的网站上.

use strict;
use EV;
use 5.010;
use Data::Dumper;
use Date::Format;
use Mojo::UserAgent;
use URI::Escape;
use AnyEvent::Inotify::Simple;

# Fikker cdn server's 
# WARNNING: do not add "/" on url end.
my $server={
	srv1=>{ url=>'http://192.168.1.99:6780',passwd=>'0000'},
	srv2=>{ url=>'http://192.168.1.88:6780',passwd=>'0000'},
};

# Monittor DIR
my $dir='/home/www/';

#Full path of Site url
my $site_url='http://www.yiyou.org/';

# open debug =1 ,close = 0
my $debug=1;

#   ===== END CONFIG ====
my $ua = Mojo::UserAgent->new;

our $login_info= do_login($ua,$server);
our $queue;

my $w = EV::timer 2, 2, sub {
   my $q=$queue;
   $queue={};
   #say "timer print";
   for my $key(keys %{$q}){
		#say  "=>",$key;
		my $url=uri_escape($site_url.$key);
		say "site url $url" if $debug;
		
		for my $srv(keys %{$server}){
			my $try=3;
			do{
				my $post_info={
					RequestID=>'thiscache-clean',
					SessionID=>$login_info->{$srv},
					Url=>$url,
					Icase=>1,
					Rules=>0,
					WithCluster=>0
				};
				my $delurl=$server->{$srv}->{url}.'/fikker/webcache.fik?type=thiscache&cmd=cleancache';
				my $res=$ua->post($delurl => form => $post_info)->res->json;
				#print Dumper $res;
				if($res->{Return} eq  "False" ){
					if($res->{ErrorNo} eq "21"){
						$login_info= do_login($ua,$server);
						say "try relogin..." if $debug ;
					}else{
						say "ERROR:";
						say Dumper $res if $debug;
					}
				}else{
					$try=-1;
				}
				$try --;
				say "try $try" if $debug;
			}while($try > 0);
		}
   }
};
my $inotify = AnyEvent::Inotify::Simple->new(
    directory      => $dir,
    event_receiver => sub {
        my ($event, $file, $moved_to) = @_;
		#print Dumper $event;
		given($event) {
			when('modify'){
				#my $last= (stat($dir."/".$file))[9];
				#print "modify $file ";
				#say time2str('%Y-%m-%d %X',$last)." => ".time2str('%Y-%m-%d %X',time);
				#say "modify $file "
				if($file =~/\.html$/){
					$queue->{$file}=1;
				}
				#say "modify => $file" if $debug;
			}
			when('delete'){
				if($file =~/\.html$/){
					$queue->{$file}=1;
				}
				#say "modify => $file" if $debug;
			}
        };

    },
);
 
EV::loop;

sub do_login{
	my ($ua,$srvs)=@_;
	my $rr;
	for my $srv(keys %{$srvs}){
		my $login_url=$srvs->{$srv}->{url}.'/fikker/webcache.fik?type=sign&cmd=in';
		#print $login_url;
		my $post_data={
				RequestID=>'LOGIN',
				Username=>'admin',
				Password=>$srvs->{$srv}->{passwd}
		};
			
		my $res= $ua->post($login_url => form => $post_data)->res->json;
		#print Dumper $res;exit;
		if($res->{SessionID}){
			$rr->{$srv}=$res->{SessionID};
		}else{
			die "[$srv] login error.";
		}
	}
	return $rr;
}

 

跟据nginx日志统计ip访问量排名

很多时候想知道哪些ip访问量最多,所以写了下面的脚本来统计一下,然后找出这些IP来自哪个国家的。

#www.yiyou.org
use strict;
use 5.010;
use Geo::IP;
use Data::Dumper;

my $file=shift;

open(FH,"$file") or die $!; 
our %counter;
my $test=1;

my $gi = Geo::IP->open("GeoLiteCity.dat", GEOIP_STANDARD);

while(<FH>){
	chomp $_;
	if(/((\d{1,3}\.){3}\d{1,3})/){
		#say $1;
		$counter{$1}+=1;
	}

}

foreach (sort{$counter{$b}<=>$counter{$a}} keys %counter){
	next if $counter{$_} < 1000;
	my $record = $gi->record_by_addr($_);
	my $country_code=$record->{country_code};
	print "$country_code $_ => $counter{$_}\n";
}

 

mojo::webqq两个群消息相互联通

很早很早之前就看到一个这样的功能,当时在extmail的两个群hzqbbc用net::oicq模块写了一个程序,然后将两个群的信息互通起来,这个功能令人羡慕妒忌恨啊,当然也没有办法要得到代码。今天正好想到webqq ,所以在cpan找到了灰灰大侠的webqq模块,功能实在太强了,所以我利用灰灰大侠的webqq实现了这个小功能。这也算圆梦了。
注意,登录qq必须要先加两个群才能进行消息转发。

use Mojo::Webqq;
use Mojo::Util qw(md5_sum);

my $qq = 111111; # 你的qq号           
my $pwd = "aaaaaaaaa"; #QQ密码
my $pwd_md5 = md5_sum($pwd);

my $client=Mojo::Webqq->new(
    ua_debug    =>  0,        
    log_level   =>  "info" ,
    qq          =>  $qq, 
    pwd         =>  $pwd_md5,
    login_type  =>  "qrlogin",
    'tmpdir'	=>'D:\\Dwimperl\\test_fy\\qq'
);
$client->load("ShowMsg");


$client->on(receive_message=>sub{
    my ($client,$msg)=@_;
    
    #$msg->dump();# 要先用这个dump 功能才能看到groupid
    if($msg->{group_id} eq 2436979435){  
	my $sender= $msg->{sender};
	my $nick=$sender->{nick};
	my $qq = $sender->{qq};
	
	my $group = $client->search_group(gname=>"LINUX/UNIX"); #转发的QQ群名字
	$client->send_group_message($group,$nick.'['.$qq.']:'.$msg->content);
    } 
    if($msg->{group_id} eq 3067430334){
	my $sender= $msg->{sender};
	my $nick=$sender->{nick};
	my $qq = $sender->{qq};
	my $group = $client->search_group(gname=>"windows企业技术");  #转发的QQ群名字
	#$client->send_group_message($group,$msg->content);
	$client->send_group_message($group,$nick.'['.$qq.']:'.$msg->content);
    } 
    
    #$msg->reply($msg->content); #已以相同内容回复接收到的消息
    #你也可以使用$msg->dump() 来打印消息结构
});

$client->on(ready=>sub{
    my $client = shift;
 
    #你的代码写在此处 
 
});

$client->run();

参考

https://metacpan.org/pod/Mojo::Webqq

宅男福利-perl爬虫-下载美女网站图片

今早想看看go的,结果google带我进入了一个go爬虫的程序的项目,下载试用了一下,发现居然不理想,想想perl不是专干这个的嘛,所以就有了以下代码

use strict;
use strict;
use WWW::Mechanize;
use Bloom::Filter;
use 5.010;
#use URI;

$|=1;

my $dir="./images/";
if(!-d $dir){
	mkdir $dir;
}

my $filter = Bloom::Filter->new(capacity => 100000, error_rate => 0.0001);

my $mech = WWW::Mechanize->new(stack_depth     => 0, timeout         => 10,autocheck       => 0);
$mech->agent_alias( 'Windows IE 6' );
$mech->add_header( Referer => 'https://meizi.us/' );

my @queue;

push @queue,"https://meizi.us/";

while(my $http=pop(@queue)){
	say "open url:".$http;
	$mech->get($http);
	for my $link($mech->links()){
		my $url=$link->url();
		#say "link $url";
		if($url=~/page=/){
			if(!$filter->check($url)){
				$filter->add($url);
				push @queue,$url;
			}
		}

	}
	for my $img($mech->images){
		my $url=$img->url;
		#say "image  $url";
		if($url=~/small\.jpg/){
			
			$url=~s/_small//;
			say "download image: $url";
			my ($file) = $url =~ m|([^/]+\z)|;;
			#say $file;
			my $ff=$dir.$file;
			if(!-f $ff){
				eval{
					$mech->get($url, ':content_file' => $dir.$file);
				};
				next if($@);
			}
			#exit;
		}
	}
	say "New counter:",scalar (@queue);
	sleep 1;
}

效果嘛,有点不好意思发了,反正准备一个大硬盘就对了

参考

http://www.php-oa.com/2013/05/24/mojo-perl-crawler.html

https://metacpan.org/pod/WWW::Mechanize#new

http://stackoverflow.com/questions/31539687/how-do-i-download-an-image-file-from-a-website-using-wwwmechanize

https://github.com/qibin0506/Meizar  –前面所说的go 项目

用perl访问带有图片验证码的后台

有时候好奇的想,如果用perl去访问一个带有图片验证码登录的用户中心,怎么用perl登录呢?先是想到 获取图片验证码,然后用orc 技术去破解,但是想到像discuz这样的验证码肯定识别率极低。后来在网上google 了一下,发现解决思路是这样的

先访问网站,找到图片验证码的路径,然后把图片下载下来(注意要同一个浏览器进程)保存成一个图片,然后人工识别这个图片,再手工输入即可了,这种方法,可以破解99% 的图片验证码

网上找来的参考代码如下

use strict;
use warnings;
use FindBin qw($Bin);
#use HTML::TreeBuilder::XPath;
use WWW::Mechanize;

my $mech = WWW::Mechanize->new();
$mech->agent_alias("Windows IE 6");
$mech->get(
    "http://epaper.dfdaily.com/dfzb/page/1/2013-08/17/A01/20130817A01_pdf.pdf");

#you don't need commented code
#because CAPTCHA URL is always the same for this site
#my $tree = HTML::TreeBuilder->new_from_content( $mech->content() );
#my ($src) = $tree->findvalues('//img[@id="checkcode"]');
$mech->get("http://203.156.244.168:9000/validatecodegen");
open my $fh, ">:raw", "$Bin/captcha.jpg" or die $!;
print {$fh} $mech->content();
close $fh;
$mech->back();

print "Input CAPTCHA: ";
my $code = <>;
chomp $code;
$mech->submit_form(

    with_fields => {
        checkCode => $code,

    },
    button => "Submit",
);

$mech->save_content("$Bin/result.pdf");

来源

http://stackoverflow.com/questions/18289338/how-to-use-perl-to-download-a-file-which-need-a-code-confirm

perl中文转换小结

每次遇到中文转换都头痛欲裂,经过这次的小程序,终于明白了perl中文字符内码转换原则。

1、perl里面只有两种字符格式Ascii(octets)和utf8(string).  所以你的程序里面只能用这两种。如果你有中文,那么肯定必须使用utf8 了。文件也要保存为utf8 格式,文件头要加上 use utf8.

notepad++里选择 “格式”-“以UTF8格式编码”

2、中文常用有 gbk,gb2312,utf8 。gb2312 和gbk是一样的,只不过gbk支持的字符要多点。你在转换时,必须知道源来的编码是什么,通常,如果你是perl文件,并以utf8 格式保存,那么这个原来的编码就是utf8了。所以,如果要转换成gbk那么程序如下

use Encode;

$str='我是中文';
$newstr= encode('gbk',decode('utf-8',$str));
# $newstr 现在已经是gbk内码了

3、mysql字符集问题,刚才已经说到,perl只支持两种格式,所以你的mysql数据库,表,字段格式也必须是utf8 的,否则麻烦很多。

4、关于perl在windows环境打印中文的问题,因为windows 中文版是gbk格式的,所以如果你是utf8 ,必需转码才能输出内容。

say encode("gbk",decode("utf-8",$str));

5、关于网页采集的问题,国内中文网站有gbk,有utf8的,所以最好先看看编码是什么的,这样就不用猜了。如果你不知道编码,下在用下面的程序猜(来自php-oa.com)

use Encode;
use LWP::Simple qw(get);
use strict;
 
my $str = get "http://www.sina.com.cn";
 
eval {my $str2 = $str; Encode::decode("gbk", $str2, 1)};
print "not gbk: $@\n" if $@;
 
eval {my $str2 = $str; Encode::decode("utf8", $str2, 1)};
print "not utf8: $@\n" if $@;
 
eval {my $str2 = $str; Encode::decode("big5", $str2, 1)};
print "not big5: $@\n" if $@;

获取到你想要的中文后,还是一样的操作,如果网页是utf8 的,可以直接插入mysql(utf8字段),如果你的字段不是utf8 ,那么转换再插入,不过建议还是选择utf8 。

对于操作mysql 前,需要执行set names utf8,程序大约如下

#get the record from  mysql
my $dbi = DBIx::Custom->connect(
  dsn => "dbi:mysql:database=mydb",
  user => 'root',
  password => '',
);

$dbi->do("SET NAMES utf8"); #注意dbix 和 DBI 都可用

 

6、关于url encode的问题,网页请求带有中文url 的时候,必须转换编码,平时可能没有注意到,gbk 和utf8 的编码是不一样的。具体到http://tool.chinaz.com/tools/urlencode.aspx  可以测试。下面的程序来自(PerlChina 552603群友)

use strict;
use warnings;
use utf8;
use 5.010;
use Data::Dumper;
use URI::Escape;
use Encode;

my $str='中文字符';

say uri_escape_utf8($str);
say uri_escape(encode("gbk",$str));

参考

http://www.php-oa.com/2008/12/13/perl-unicode.html

perlcn – 简体中文 Perl 指南

来自 http://docs.activestate.com/activeperl/5.8/lib/pods/perlcn.html

 

perlcn – 简体中文 Perl 指南


DESCRIPTION

欢迎来到 Perl 的天地!

从 5.8.0 版开始, Perl 具备了完善的 Unicode (统一码) 支援, 也连带支援了许多拉丁语系以外的编码方式; CJK (中日韩) 便是其中的一部份. Unicode 是国际性的标准, 试图涵盖世界上所有的字符: 西方世界, 东方世界, 以及两者间的一切 (希腊文, 叙利亚文, 亚拉伯文, 希伯来文, 印度文, 印地安文, 等等). 它也容纳了多种作业系统与平台 (如 PC 及麦金塔).

Perl 本身以 Unicode 进行操作. 这表示 Perl 内部的字符串数据可用 Unicode 表示; Perl 的函式与算符 (例如正规表示式比对) 也能对 Unicode 进行操作. 在输入及输出时, 为了处理以 Unicode 之前的编码方式存放的数据, Perl 提供了 Encode 这个模块, 可以让你轻易地读取及写入旧有的编码数据.

Encode 延伸模块支援下列简体中文的编码方式 (‘gb2312’ 表示 ‘euc-cn’):

    euc-cn      Unix 延伸字符集, 也就是俗称的国标码
    gb2312-raw  未经处理的 (低比特) GB2312 字符表
    gb12345     未经处理的中国用繁体中文编码
    iso-ir-165  GB2312 + GB6345 + GB8565 + 新增字符
    cp936       字码页 936, 也可以用 'GBK' (扩充国标码) 指明
    hz          7 比特逸出式 GB2312 编码

举例来说, 将 EUC-CN 编码的档案转成 Unicode, 祗需键入下列指令:

    perl -Mencoding=euc-cn,STDOUT,utf8 -pe1 < file.euc-cn > file.utf8

Perl 也内附了 “piconv”, 一支完全以 Perl 写成的字符转换工具程序, 用法如下:

    piconv -f euc-cn -t utf8 < file.euc-cn > file.utf8
    piconv -f utf8 -t euc-cn < file.utf8 > file.euc-cn

另外, 利用 encoding 模块, 你可以轻易写出以字符为单位的程序码, 如下所示:

    #!/usr/bin/env perl
    # 启动 euc-cn 字串解析; 标准输出入及标准错误都设为 euc-cn 编码
    use encoding 'euc-cn', STDIN => 'euc-cn', STDOUT => 'euc-cn';
    print length("骆驼");            #  2 (双引号表示字符)
    print length('骆驼');            #  4 (单引号表示字节)
    print index("谆谆教诲", "蛔唤"); # -1 (不包含此子字符串)
    print index('谆谆教诲', '蛔唤'); #  1 (从第二个字节开始)

在最后一列例子里, “谆” 的第二个字节与 “谆” 的第一个字节结合成 EUC-CN 码的 “蛔”; “谆” 的第二个字节则与 “教” 的第一个字节结合成 “唤”. 这解决了以前 EUC-CN 码比对处理上常见的问题.

额外的中文编码

如果需要更多的中文编码, 可以从 CPAN (http://www.cpan.org/) 下载 Encode::HanExtra 模块. 它目前提供下列编码方式:

    gb18030     扩充过的国标码, 包含繁体中文

另外, Encode::HanConvert 模块则提供了简繁转换用的两种编码:

    big5-simp   Big5 繁体中文与 Unicode 简体中文互转
    gbk-trad    GBK 简体中文与 Unicode 繁体中文互转

若想在 GBK 与 Big5 之间互转, 请参考该模块内附的 b2g.pl 与 g2b.pl 两支程序, 或在程序内使用下列写法:

    use Encode::HanConvert;
    $euc_cn = big5_to_gb($big5); # 从 Big5 转为 GBK
    $big5 = gb_to_big5($euc_cn); # 从 GBK 转为 Big5

进一步的信息

请参考 Perl 内附的大量说明文件 (不幸全是用英文写的), 来学习更多关于 Perl 的知识, 以及 Unicode 的使用方式. 不过, 外部的资源相当丰富:

提供 Perl 资源的网址

http://www.perl.com/
Perl 的首页 (由欧莱礼公司维护)
http://www.cpan.org/
Perl 综合典藏网 (Comprehensive Perl Archive Network)
http://lists.perl.org/
Perl 邮递论坛一览

学习 Perl 的网址

http://www.oreilly.com.cn/html/perl.html
简体中文版的欧莱礼 Perl 书藉

Perl 使用者集会

http://www.pm.org/groups/asia.html
中国 Perl 推广组一览

Unicode 相关网址

http://www.unicode.org/
Unicode 学术学会 (Unicode 标准的制定者)
http://www.cl.cam.ac.uk/%7Emgk25/unicode.html
Unix/Linux 上的 UTF-8 及 Unicode 答客问

SEE ALSO

the Encode manpage, the Encode::CN manpage, the encoding manpage, the perluniintro manpage, the perlunicode manpage


AUTHORS

Jarkko Hietaniemi <jhi@iki.fi>

Audrey Tang (唐凤) <audreyt@audreyt.org>